*Jan 2, 2006
*Doc. ID: 77515, S-52635, Rev. B
.SUBCKT TP0202K 4 1 2
M1  3 1 2 2 PMOS W=26124u L=0.50u   
M2  2 1 2 4 NMOS W=26124u L=1.20u    
R1  4 3     RTEMP 30E-2
CGS 1 2     22E-12
DBD 4 2     DBD
**************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3            TOX    = 5E-8
+ RS     = 80E-2           RD     = 0            NSUB   = 5.5E16   
+ KP     = 1E-5            UO     = 400             
+ VMAX   = 0               XJ     = 5E-7         KAPPA  = 5E-2
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                
+ CGSO   = 0               CGDO   = 0            CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5         TCV    = 3.4E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3            TOX    = 5E-8
+NSUB    = 2E16            NFS    = 1E12 )   
**************************************************************** 
.MODEL DBD D (CJO=18E-12 VJ=0.38 M=0.28
+RS=1 FC=0.5 IS=1E-12 TT=5E-8 N=1 BV=31)
**************************************************************** 
.MODEL RTEMP R (TC1=9E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS