*June 13, 2005
*Doc. ID: 77526, S-51095, Rev. B
*File Name: Si4430BDY_PS.txt and Si4430BDY_PS.lib
.SUBCKT Si4430DBY 4 1 2
M1  3 1 2 2 NMOS W=6370507u L=0.25u  
M2  2 1 2 4 PMOS W=6370507u L=0.20u  
R1  4 3     RTEMP 1.85E-3
CGS 1 2     2000E-12
DBD 2 4     DBD
************************************************************  
.MODEL  NMOS         NMOS (LEVEL  = 3        TOX    = 5E-8
+ RS     = 1.5E-3          RD     = 0        NSUB   = 2.78E17  
+ KP     = 1.4E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7     KAPPA  = 1E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0        CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
************************************************************  
.MODEL  PMOS         PMOS (LEVEL  = 3        TOX    = 3E-8
+NSUB    = 3E16            TPG    = -1)   
************************************************************  
.MODEL DBD D (CJO=1200E-12 VJ=0.38 M=0.29
+RS=0.01 FC=0.1 IS=1E-12 TT=2.8E-8 N=1 BV=30.2)
************************************************************ 
.MODEL RTEMP RES (TC1=7E-3 TC2=5.5E-6)
************************************************************  
.ENDS