*July 27, 2005
*Doc. ID: 77530, S-51303, Rev. B
.SUBCKT Si4483EDY 4 1 2
M1   3 5 2 2 PMOS W=6510918u L=0.25u               
M2   2 5 2 4 NMOS W=6510918u L=0.50u      
R1   4 3     RTEMP 4E-3
CGS  5 2     200E-12
DBD  4 2     DBD
XESD 1 5 2   Si4483EDY_ESD
**************************************************************  
.MODEL  PMOS        PMOS ( LEVEL  = 3          TOX    = 5E-8
+ RS     = 1.5E-3          RD     = 0          NSUB   = 9E16
+ KP     = 3.1E-6          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7       KAPPA  = 2E-1
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0          CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5       TCV    = 4.3E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3          TOX    = 5E-8
+NSUB    = 9E16            TPG    = -1)   
************************************************************** 
.MODEL DBD D (CJO=150E-12 VJ=0.38 M=0.33
+RS=0.1 FC=0.5 IS=1E-12 TT=6E-8 N=1 BV=30.2)
************************************************************** 
.MODEL RTEMP R (TC1=5E-3 TC2=5.5E-6)
************************************************************** 
.ENDS Si4483EDY
.subckt Si4483EDY_ESD 1 5 2
rleak 2 9 75660 TC=-7.276e-3
dleak 9 1 dleak  
.MODEL dleak d (IS=1e-7 XTI=815.6 EG=1.17 TREF=25 TCV=1e-3 N=60.42 BV=50)
rout 2 10 244.6 TC=-4.371e-3
dout1 10 11 dout
dout2 11 12 dout
dout3 12 13 dout
dout4 13 14 dout
dout5 1  14 dout
.MODEL dout D (IS=1e-7 XTI=-9.567 EG=1.17 TREF=25 TCV=1e-2 N=3.964 BV=20)
rpoly 1 5 7200 TC=8e-4
rin 2 20 8332 TC=-4e-3
din1 20 21 din
din2 21 22 din
din3 22 23 din
din4 5 23 din
.MODEL din D (IS=1e-7 XTI=11.27 EG=1.17 TREF=25 TCV=1e-2 N=2.996 BV=16.61)
.ends Si4483EDY_ESD