*Dec 12, 2005
*Doc. ID: 77535, S-52518, Rev. C
*File Name: Si3853DV_PS.txt and Si3853DV_PS.lib
.SUBCKT Si3853DV D G S A K
X1 D G S Si3853
X2 A K   Si3853_SCH
.ENDS Si3853DV
.SUBCKT Si3853 D G S
M1  3 G S S PMOS W=828290u L=0.25u  
M2  S G S D NMOS W=828290u L=0.40u
R1  D 3     RTEMP 10E-3
CGS G S     45E-12
DBD D S     DBD
**************************************************************** 
.MODEL  PMOS         PMOS (LEVEL  = 3           TOX    = 3E-8
+ RS     = 130E-3          RD     = 0           NSUB   = 3.6E16   
+ KP     = 2.6E-6          UO     = 400           
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 1E-2
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                 
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  NMOS         NMOS (LEVEL  = 3           TOX    = 6E-8
+NSUB    = 7E15             NFS   = 1E12        TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=90E-12 VJ=0.38 M=0.28
+RS=0.1 FC=0.5 IS=1E-12 TT=5E-8 N=1 BV=22)
**************************************************************** 
.MODEL RTEMP RES (TC1=8E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS Si3853
.subckt Si3853_SCH A K
r1 6 K rtemp 1e-4
d1 A 6 sdiode 
****************************************************
.model sdiode d (cjo=145e-12 vj=0.45 xti=2 
+rs=0.08 fc=0.5 is=1e-6 ikf=0.8 eg=0.55 n=1 bv=22)
****************************************************
.model rtemp res (tc1=0.15e-2 tc2=30e-6)
.ENDS Si3853_SCH