*Jan 2, 2006
*Doc. ID: 77548, S-52575, Rev. B
*Dn Gn Sn Dp Gp Sp
.SUBCKT Si4565DY 6 2 1 3 5 4  
X1 6 2 1 Si4565N
X2 3 5 4 Si4565P
.ENDS Si4565DY
*N-CH
.SUBCKT Si4565N 4 1 2
M1  3 1 2 2 NMOS W=1932574u L=0.50u 
M2  2 1 2 4 PMOS W=1932574u L=0.15u 
R1  4 3     RTEMP 15E-3
CGS 1 2     10E-12
DBD 2 4     DBD
************************************************************  
.MODEL  NMOS        NMOS (LEVEL  = 3        TOX    = 3E-8
+ RS     = 16.6E-3        RD     = 0        NSUB   = 1.75E17  
+ KP     = 1.8E-5         UO     = 650             
+ VMAX   = 0              XJ     = 5E-7     KAPPA  = 2.5E-1
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0                             
+ CGSO   = 0              CGDO   = 0        CGBO   = 0 
+ TLEV   = 1              BEX    = -1.5     TCV    = 2.45E-3
+ NFS    = 0.8E12         DELTA  = 0.1)
************************************************************  
.MODEL  PMOS        PMOS (LEVEL  = 3        TOX    = 3E-8
+NSUB    = 5E16           TPG    = -1)   
************************************************************  
.MODEL DBD D (CJO=130E-12 VJ=0.38 M=0.30
+RS=0.01 FC=0.1 IS=1E-12 TT=5E-8 N=1 BV=40.2)
************************************************************ 
.MODEL RTEMP R (TC1=9E-3  TC2=5.5E-6)
************************************************************  
.ENDS Si4565N
*P-CH
.SUBCKT Si4565P 4 1 2   
M1  3 1 2 2 PMOS W=1256354u L=0.25u           
M2  2 1 2 4 NMOS W=1256354u L=0.45u  
R1  4 3     RTEMP 18E-3
CGS 1 2     500E-12
DBD 4 2     DBD
***************************************************************  
.MODEL  PMOS       PMOS  ( LEVEL  = 3          TOX    = 4E-8
+ RS     = 20E-3           RD     = 0          NSUB   = 8.5E16
+ KP     = 4E-6            UO     = 400             
+ VMAX   = 0               XJ     = 5E-7       KAPPA  = 1.2E-1
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0          CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5       TCV    = 3.7E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS       NMOS  ( LEVEL  = 3          TOX    = 4E-8
+NSUB    = 6E16            TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=140E-12 VJ=0.38 M=0.34
+RS=0.1 FC=0.5 IS=1E-12 TT=6E-8 N=1 BV=40.2)
*************************************************************** 
.MODEL RTEMP R (TC1=10E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS Si4565P