*April 4, 2005
*Doc. ID: 77671, S-50588, Rev. A
*File Name: Si7530DP_PS.txt and Si7530DP_PS.lib
*Dn Gn Sn Dp Gp Sp
.SUBCKT Si7530DP 6 2 1 3 5 4  
X1 6 2 1 Si7530N
X2 3 5 4 Si7530P
.ENDS Si7530DP
*N-CH
.SUBCKT Si7530N 4 1 2
M1  3 1 2 2 NMOS W=581751u L=0.25u     
M2  2 1 2 4 PMOS W=581751u L=0.50u 
R1  4 3     RTEMP 35E-3  
CGS 1 2     520E-12
DBD 2 4     DBD
**************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3            TOX    = 5E-8
+ RS     = 16E-3           RD     = 0            NSUB   = 2E17
+ KP     = 7E-6            U0     = 650
+ VMAX   = 0               XJ     = 5E-7         KAPPA  = 2E-3
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0            CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3            TOX    = 5E-8
+NSUB    = 2.2E16          TPG    = -1)           
 *************************************************************** 
.MODEL DBD D (CJO=370E-12 VJ=0.38 M=0.35
+RS=0.1 FC=0.1 IS=1E-12 TT=5E-8 N=1 BV=60.2)
**************************************************************** 
.MODEL RTEMP RES (TC1=9E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS Si7530N
*P-CH
.SUBCKT Si7530P 4 1 2
M1  3 1 2 2 PMOS W=2036637u L=0.25u           
M2  2 1 2 4 NMOS W=2036637u L=0.45u 
R1  4 3     RTEMP 39E-3 
CGS 1 2     1000E-12
DBD 4 2     DBD
***************************************************************  
.MODEL  PMOS       PMOS  ( LEVEL  = 3          TOX    = 5E-8
+ RS     = 6E-3            RD     = 0          NSUB   = 1.2E17
+ KP     = 3.5E-6          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7       KAPPA  = 7E-2
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0          CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS       NMOS  ( LEVEL  = 3          TOX    = 5E-8
+NSUB    = 2E16            TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=200E-12 VJ=0.38 M=0.27
+RS=0.1 FC=0.5 IS=1E-12 TT=6E-8 N=1 BV=60.5)
*************************************************************** 
.MODEL RTEMP RES (TC1=7E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS Si7530P