*Jan 2, 2006
*Doc. ID: 77714, S-52633, Rev. A
*File Name: Si6924AEDQ_PS.txt and Si6924AEDQ_PS.lib
.SUBCKT Si6924AEDQ 4 1 2
M1   3 1 2 2 NMOS W=2189408u L=0.50u   
M2   2 1 2 4 PMOS W=2189408u L=0.25u  
R1   4 3     RTEMP 11.6E-3
CGS  1 2     40E-12
DBD  2 4     DBD
xesd 1 5 2   Si6924AEDQ_esd
************************************************************  
.MODEL  NMOS        NMOS ( LEVEL  = 3        TOX    = 3E-8
+ RS     = 7E-3            RD     = 0        NSUB   = 1.76E17  
+ KP     = 2.6E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7     KAPPA  = 2E-1
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0        CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
************************************************************  
.MODEL  PMOS        PMOS ( LEVEL  = 3        TOX    = 3E-8
+NSUB    = 1E15            TPG    = -1)   
************************************************************  
.MODEL DBD D (CJO=3900E-12 VJ=0.38  M=0.30
+RS=0.01 FC=0.1 IS=1E-12 TT=5.8E-8 N=1 BV=20.2)
************************************************************ 
.MODEL RTEMP RES (TC1=8E-3  TC2=5.5E-6)
************************************************************  
.ENDS Si6924AEDQ
.subckt Si6924AEDQ_esd 1 5 2
rleak 1 9 64.25K $TC=0 
dleak 9 2 dleak  
.MODEL dleak d (IS=2.178e-9 XTI=425.3 EG=1.17 T_MEASURED=25 TBV1=0 N=37.64 BV=50) 
rout 1 10 98.37 $TC=-0.002
d3 11 10 dout 1.422 
d4 11 12 dout 1.422
d5 13 12 dout 1.472
d6 13 2  dout 1.472
.MODEL dout D (IS=3.03e-8 XTI=-35 EG=1.17 T_MEASURED=25 TBV1=-6.154e-4 N=2.494 BV=6.552)
rpoly 1 5 2.2K TC=0.001
rd8 5 14 800.5 
d8 15 14 din  	
d9 15 2  din  
.MODEL din D (IS=1e-11 XTI=-17.81 EG=1.17 T_MEASURED=25 TBV1=-1.575e-4 N=1.932 BV=6.351)
.ends Si6924AEDQ_esd