*Nov 21, 2005
*Doc. ID: 77767, S-52395, Rev. B
.SUBCKT Si4845DY D G S A K
X1 D G S Si4845
X2 A K   Si4845_SCH
.ENDS Si4845DY
.SUBCKT Si4845 D G S
M1  3 G S S PMOS W=828290u L=0.25u  
M2  S G S D NMOS W=828290u L=0.40u 
R1  D 3     RTEMP 5E-2
CGS G S     20E-12
DBD D S     DBD
*************************************************************** 
.MODEL  PMOS         PMOS (LEVEL  = 3           TOX    = 3E-8
+ RS     = 8E-2            RD     = 0           NSUB   = 4E16   
+ KP     = 2E-6            UO     = 400           
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 1E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                 
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5        TCV    = 2.7E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS         NMOS (LEVEL  = 3           TOX    = 3E-8
+NSUB    = 7E15            NFS    = 1E12        TPG    = -1)   
**************************************************************  
.MODEL DBD D (CJO=90E-12 VJ=0.38 M=0.28
+RS=0.1 FC=0.5 IS=1E-12 TT=5E-8 N=1 BV=22)
***************************************************************  
.MODEL RTEMP R (TC1=12E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS Si4845 
.subckt Si4845_SCH A K
r1 6 K  rtemp 0.036
d1 A 6  sdiode 
****************************************************
.model sdiode d (cjo=300e-12 vj=0.38 xti=2 
+rs=0 fc=0.5 is=1.4e-6 ik=0.85 eg=0.69 n=1 bv=32)
*****************************************************
.model rtemp r (tc1=0.31e-2 tc2=30e-6)
.ENDS Si4845_SCH