*Jan 2, 2006
*Doc. ID: 77853, S-52633, Rev. A
.SUBCKT Si8404DB 4 1 2
M1  3 1 2 2 NMOS W=1389432u L=0.25u   
M2  2 1 2 4 PMOS W=1389432u L=0.33u   
R1  4 3     RTEMP 16E-3
CGS 1 2     1400E-12
DBD 2 4     DBD
**************************************************************** 
.MODEL  NMOS       NMOS ( LEVEL  = 3            TOX    = 1.3E-8
+ RS     = 8E-3           RD     = 0            NSUB   = 4.53E17  
+ KP     = 4E-5           UO     = 650             
+ VMAX   = 0              XJ     = 5E-7         KAPPA  = 5E-2
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0               
+ CGSO   = 0              CGDO   = 0            CGBO   = 0 
+ TLEV   = 1              BEX    = -1.5         TCV    = 2E-3
+ NFS    = 0.8E12         DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS       PMOS ( LEVEL  = 3            TOX    = 1.3E-8
+NSUB    = 2.5E17         TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=470E-12 VJ=0.38 M=0.21
+RS=0.1 FC=0.5 IS=1E-12 TT=5E-8 N=1 BV=8.2)
**************************************************************** 
.MODEL RTEMP R (TC1=5E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS