*Oct 31, 2005
*Doc. ID: 78230, S-52282, Rev. A
.SUBCKT Si8417DB D G S
M1  3 G S S PMOS W=2560118u L=0.50u 
M2  S G S D NMOS W=2560118u L=0.30u 
R1  D 3     RTEMP 6E-3
CGS G S     100E-12
DBD D S     DBD
**************************************************************** 
.MODEL  PMOS         PMOS (LEVEL  = 3           TOX    = 1.7E-8
+ RS     = 10.5E-3         RD     = 0           NSUB   = 9E15   
+ KP     = 2.9E-5          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 5E-2
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                 
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5        TCV    = 1.6E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
***************************************************************** 
.MODEL  NMOS         NMOS (LEVEL  = 3           TOX    = 1.7E-8
+NSUB    = 4E17            TPG    = -1)   
***************************************************************** 
.MODEL DBD D (CJO=600E-12 VJ=0.38 M=0.17
+RS=0.1 FC=0.5 IS=1E-12 TT=6.7E-8 N=1 BV=20.5)
***************************************************************** 
.MODEL RTEMP R (TC1=12E-3 TC2=5.5E-6)
***************************************************************** 
.ENDS