*Nov 28, 2005
*Doc. ID: 78283, S-52447, Rev. A
.SUBCKT Si4563DY D1 G1 S1 D2 G2 S2
X1 D1 G1 S1 Si4563N
X2 D2 G2 S2 Si4563P
.ENDS Si4563DY
*N-CH
.SUBCKT Si4563N D G S
M1  3 G S S NMOS W=3708309u L=0.25u  
M2  S G S D PMOS W=3708309u L=0.50u   
R1  D 3     RTEMP 6E-3
CGS G S     2200E-12
DBD S D     DBD
**************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 5E-8
+ RS     = 6.2E-3          RD     = 0           NSUB   = 1.63E17   
+ kp     = 8.5E-6          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 1E-3
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5        TCV    = 3.7E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 5E-8
+NSUB    = 2E16            TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=400E-12 VJ=0.38 M=0.34 
+FC=0.1 IS=1E-12 TT=9.3E-8 N=1 BV=40.2)
**************************************************************** 
.MODEL RTEMP R (TC1=8.5E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS Si4563N
*P-CH
.SUBCKT Si4563P D G S
M1  3 G S S PMOS W=3481643u L=0.25u           
M2  S G S D NMOS W=3481643u L=0.50u 
R1  D 3     RTEMP 6E-3
CGS G S     1500E-12
DBD D S     DBD
***************************************************************  
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 4E-8
+ RS     = 11.3E-3         RD     = 0           NSUB   = 1.04E17
+ KP     = 4.1E-6          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 4E-2
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5        TCV    = 3E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 4E-8
+NSUB    = 4E16            TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=400E-12 VJ=0.38 M=0.33
+RS=0.1 FC=0.5 IS=1E-12 TT=6E-8 N=1 BV=41)
*************************************************************** 
.MODEL RTEMP R (TC1=12E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS Si4563P