*Feb 20, 2006
*Doc. ID: 78320, S-60243, Rev. A
*File Name: Si4567DY_PS.txt and Si4567DY_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si4567DY Dn Gn Sn Dp Gp Sp 
X1 Dn Gn Sn Si4567N
X2 Dp Gp Sp Si4567P
.ENDS Si4567DY
*N-CH
.subckt Si4567N D G S
m1  3 G S S nmos w=527353u l=0.25u
m2  S G S D pmos w=527353u l=0.30u
r1  D 3     rtemp 20e-3
cgs G S     350e-12
dbd S D     dbd
****************************************************************
.model  nmos        nmos ( level  = 3           tox    = 4e-8
+ rs     = 26e-3           rd     = 0           nsub   = 2.45e17
+ kp     = 1.9e-5          uo     = 650
+ vmax   = 0               xj     = 5e-7        kappa  = 2e-1
+ eta    = 1e-4            tpg    = 1
+ is     = 0               ld     = 0
+ cgso   = 0               cgdo   = 0           cgbo   = 0
+ nfs    = 0.8e12          delta  = 0.1)
**************************************************************** 
.model  pmos        pmos ( level  = 3           tox    = 4e-8
+nsub    = 6e16            tpg    = -1)
****************************************************************
.model dbd d (cjo=95e-12 vj=0.38 m=0.30
+fc=0.1 is=1e-12 tt=6e-8 n=1 bv=41)
****************************************************************
.model rtemp res (tc1=8e-3 tc2=5.5e-6)
****************************************************************
.ENDS Si4567N
*P-CH
.SUBCKT Si4567P D G S
M1  3 G S S PMOS W=734849u L=0.25u          
M2  S G S D NMOS W=734849u L=0.50u
R1  D 3     RTEMP 18E-3
CGS G S     350E-12
DBD D S     DBD
***************************************************************  
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 4E-8
+ RS     = 38E-3           RD     = 0           NSUB   = 1.2E17
+ KP     = 4E-6            UO     = 400             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 1E-2
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 4E-8
+NSUB    = 6E16            TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=70E-12 VJ=0.38 M=0.33
+RS=0.1 FC=0.5 IS=1E-12 TT=6E-8 N=1 BV=41)
*************************************************************** 
.MODEL RTEMP RES (TC1=13E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS Si4567P