*May 1, 2006
*Doc. ID: 78370, S-60675, Rev. A
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si5480DU D G S
M1  3 G S S NMOS W=1936784u L=0.25u  
M2  S G S D PMOS W=1936784u L=0.30u   
R1  D 3     RTEMP 4.5E-3
CGS G S     1000E-12
DBD S D     DBD
**************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 5E-8
+ RS     = 6.5E-3          RD     = 0           NSUB   = 2.85E17   
+ kp     = 1E-5            UO     = 650             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 1E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5        TCV    = 5E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 5E-8
+NSUB    = 5E16            TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=300E-12 VJ=0.38 M=0.26 
+FC=0.1 IS=1E-12 TT=9.3E-8 N=1 BV=30.2)
**************************************************************** 
.MODEL RTEMP R (TC1=11E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS