*March 20, 2006
*Doc. ID: 78605, S-60411, Rev. A
*File Name: Si5482DU_PS.txt and Si5482DU_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si5482DU D G S
M1  3  GX S S NMOS W=1936784u L=0.25u
M2  S  GX S D PMOS W=1936784u L=0.30u 
RG  G  GX     5.1 
R1  D  3      RTEMP 6.4E-3
CGS GX S      1400E-12
DBD S  D      DBD
************************************************************  
.MODEL  NMOS         NMOS (LEVEL  = 3        TOX    = 3E-8
+ RS     = 5E-3            RD     = 0        NSUB   = 2.86E17  
+ KP     = 1.62E-5         UO     = 650             
+ VMAX   = 0               XJ     = 5E-7     KAPPA  = 1E-1
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0        CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
************************************************************  
.MODEL  PMOS         PMOS (LEVEL  = 3        TOX    = 3E-8
+NSUB    = 3E16            TPG    = -1)   
************************************************************  
.MODEL DBD D (CJO=300E-12 VJ=0.38 M=0.22
+RS=0.01 FC=0.1 IS=1E-12 TT=1.44E-8 N=1 BV=30.2)
************************************************************ 
.MODEL RTEMP RES (TC1=7E-3 TC2=5.5E-6)
************************************************************  
.ENDS