*March 20, 2006
*Doc. ID: 79221, S-60411, Rev. A
*File Name: Si5509DC_PS.txt and Si5509DC_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
*D1 G1 S1 D2 G2 S2
.SUBCKT Si5509DC 6 2 1 3 5 4  
X1 6 2 1 Si5509N
X2 3 5 4 Si5509P
.ENDS Si5509DC
*N-CH
.SUBCKT Si5509N D G S
M1  3  GX S S NMOS W=485249u L=0.25u  
M2  S  GX S D PMOS W=485249u L=0.40u 
RG  G  GX     1.9
R1  D  3      RTEMP 14.5E-3
CGS GX S      365E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 3E-8
+ RS     = 16E-3           RD     = 0           NSUB   = 3E17   
+ kp     = 1.9E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 2E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 3E-8
+NSUB    = 2.5E16          TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=100E-12 VJ=0.38 M=0.20
+FC=0.1 IS=1E-12 TT=8.53E-9 N=1 BV=20.2)
**************************************************************** 
.MODEL RTEMP RES (TC1=8E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS Si5509N
*P-CH
.SUBCKT Si5509P D G S
M1  3  GX S S PMOS W=399031u L=0.25u            
M2  S  GX S D NMOS W=399031u L=0.45u 
R   G  GX     8
R1  D  3      RTEMP 20E-3
CGS GX S      200E-12
DBD D  S      DBD
***************************************************************  
.MODEL  PMOS        PMOS ( LEVEL  = 3          TOX    = 3E-8
+ RS     = 24.5E-3         RD     = 0          NSUB   = 4.5E16
+ KP     = 9.5E-6          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7       KAPPA  = 5E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0          CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3          TOX    = 3E-8
+NSUB    = 1.5E17          TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=60E-12 VJ=0.38 M=0.20
+RS=0.1 FC=0.5 IS=1E-12 TT=9.72E-9 N=1 BV=20.2)
*************************************************************** 
.MODEL RTEMP RES (TC1=9E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS Si5509P