*July 24, 2006
*Doc. ID: 79339, S-61262, Rev. A
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si5943DU D G S
M1  3  GX S S PMOS W=399031u L=0.25u            
M2  S  GX S D NMOS W=399031u L=0.45u 
RG  G  GX     6.4
R1  D  3      RTEMP 25.5E-3
CGS GX S      300E-12
DBD D  S      DBD
***************************************************************  
.MODEL  PMOS        PMOS ( LEVEL  = 3          TOX    = 1.7E-8
+ RS     = 9E-3            RD     = 0          NSUB   = 8E15
+ KP     = 1E-5            UO     = 400             
+ VMAX   = 0               XJ     = 5E-7       KAPPA  = 1E-4
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0          CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5       TCV    = 2.6E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3          TOX    = 1.7E-8
+NSUB    = 3.4E17          TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=150E-12 VJ=0.38 M=0.38
+RS=0.1 FC=0.5 IS=1E-12 TT=1.01E-8 N=1 BV=20.2)
*************************************************************** 
.MODEL RTEMP R (TC1=4.5E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS