*June 12, 2006
*Doc. ID: 79624, S-60992, Rev. A
*File Name: Si5485DU_PS.txt and Si5485DU_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si5485DU D G S
M1  3  GX S S PMOS W=1807491u L=0.25u            
M2  S  GX S D NMOS W=1807491u L=0.45u 
RG  G  GX     8
R1  D  3      RTEMP 5E-3
CGS GX S      590E-12
DBD D  S      DBD
***************************************************************  
.MODEL  PMOS        PMOS ( LEVEL  = 3          TOX    = 3E-8
+ RS     = 8E-3            RD     = 0          NSUB   = 6.3E16
+ KP     = 6.7E-6          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7       KAPPA  = 1E-2
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0          CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3          TOX    = 3E-8
+NSUB    = 1E17            TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=100E-12 VJ=0.38 M=0.15
+RS=0.1 FC=0.5 IS=1E-12 TT=1.13E-8 N=1 BV=20.2)
*************************************************************** 
.MODEL RTEMP RES (TC1=12E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS