*July 30, 2007
*Doc. ID: 79634, S-71567, Rev. A
*File Name: Si4972DY_PS.txt and Si4972DY_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
*Dn1 Gn1 Sn1 Dn2 Gn2 Sn2
.SUBCKT Si4972DY 8 2 1 6 4 3  
X1    8 2 1 Si4972C1
X2    6 4 3 Si4972C2
.ENDS Si4972DY 
*Channel 1
.SUBCKT Si4972C1 D G S
M1  3  GX S S NMOS W=1946618u L=0.25u  
M2  S  GX S D PMOS W=1946618u L=0.30u  
RG  G  GX     2.5
R1  D  3      RTEMP 5E-3
CGS GX S      840E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 5E-8
+ RS     = 6.2E-3          RD     = 0           NSUB   = 3.6E17   
+ kp     = 2.4E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 5E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 5E-8
+NSUB    = 2E16            TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=400E-12 VJ=0.38 M=0.35
+FC=0.1 IS=1E-12 TT=1.63E-8 N=1 BV=30.2)
**************************************************************** 
.MODEL RTEMP RES (TC1=9E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS Si4972C1
*Channel 2
.SUBCKT Si4972C2 D G S
M1  3  GX S S NMOS W=946643u L=0.25u  
M2  S  GX S D PMOS W=946643u L=0.30u  
RG  G  GX     2.9
R1  D  3      RTEMP 11E-3
CGS GX S      420E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 5E-8
+ RS     = 10E-3           RD     = 0           NSUB   = 3.4E17   
+ kp     = 2.3E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 5E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 5E-8
+NSUB    = 1.5E16          TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=250E-12 VJ=0.38 M=0.35
+FC=0.1 IS=1E-12 TT=1.34E-8 N=1 BV=30.2)
**************************************************************** 
.MODEL RTEMP RES (TC1=9E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS Si4972C2