*June 18, 2007
*Doc. ID: 79659, S-71182, Rev. A
*File Name: Si1072X_PS.txt and Si1072X_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si1072X D G S
M1  3  GX S S NMOS W=398935u L=0.25u  
M2  S  GX S D PMOS W=398935u L=0.35u  
RG  G  GX     3.5
R1  D  3      RTEMP 33E-3
CGS GX S      240E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 5E-8
+ RS     = 37E-3           RD     = 0           NSUB   = 3E17   
+ kp     = 1.15E-5         UO     = 650             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 2E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 5E-8
+NSUB    = 6E16            TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=50E-12 VJ=0.38 M=0.15
+FC=0.1 IS=1E-12 TT=9.01E-9 N=1 BV=30.2)
**************************************************************** 
.MODEL RTEMP RES (TC1=8E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS