*Nov 12, 2012
*ECN S12-2746, Rev. B
*File Name: Si7115DN_PS.txt and Si7115DN_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product datasheet.  Designers should refer to the
*appropriate datasheet of the same number for guaranteed specification
*limits.
.SUBCKT Si7115DN D G S
M1  3  GX S S PMOS W=2515672u L=0.25u          
M2  S  GX S D NMOS W=2515672u L=0.35u 
RG  G  GX     6.1
R1  D  3      RTEMP 12E-2
CGS GX S      940E-12
DBD D  S      DBD
***************************************************************  
.MODEL  PMOS       PMOS  ( LEVEL  = 3           TOX    = 7E-8
+ RS     = 12E-2           RD     = 0           NSUB   = 9E16
+ KP     = 4E-6            UO     = 400             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 5E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS       NMOS  ( LEVEL  = 3           TOX    = 7E-8
+NSUB    = 2E16            NFS    = 1E12 )   
*************************************************************** 
.MODEL DBD D (CJO=80E-12 VJ=0.38 M=0.34
+RS=0.1 FC=0.5 IS=1E-12 TT=7.9E-8 N=1 BV=152)
*************************************************************** 
.MODEL RTEMP RES (TC1=13E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS
