*August 27, 2007
*Doc. ID: 79799, S-71716, Rev. B
*File Name: SiA911DJ_PS.txt and SiA911DJ_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SiA911DJ D G S
M1  3  GX S S PMOS W=325941u L=0.25u            
M2  S  GX S D NMOS W=325941u L=0.30u
RG  G  GX     8
R1  D  3      RTEMP 1.05E-2
CGS GX S      240E-12
DBD D  S      DBD
***************************************************************  
.MODEL  PMOS        PMOS ( LEVEL  = 3          TOX    = 1.7E-8
+ RS     = 5E-2            RD     = 0          NSUB   = 1.4E16
+ KP     = 1.15E-5         UO     = 400             
+ VMAX   = 0               XJ     = 5E-7       KAPPA  = 2E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0          CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3          TOX    = 1.7E-8
+NSUB    = 3E17            TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=40E-12 VJ=0.38 M=0.20
+RS=0.1 FC=0.5 IS=1E-12 TT=8.68E-9 N=1 BV=20.2)
*************************************************************** 
.MODEL RTEMP RES (TC1=15E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS