*November 27, 2006
*Doc. ID: 79809, S-62311, Rev. A
*File Name: Si5511DC_PS.txt and Si5511DC_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
*D1 G1 S1 D2 G2 S2
.SUBCKT Si5511DC 6 2 1 3 5 4  
X1 6 2 1 Si5511N
X2 3 5 4 Si5511P
.ENDS Si5511DC
*N-CH
.SUBCKT Si5511N D G S
M1  3  GX S S NMOS W=485249u L=0.25u 
M2  S  GX S D PMOS W=485249u L=0.25u   
RG  G  GX     2.7
R1  D  3      RTEMP 16E-3
CGS GX S      400E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 3E-8
+ RS     = 14.5E-3         RD     = 0           NSUB   = 2.5E17   
+ kp     = 1.66E-5         UO     = 650             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 6E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 3E-8
+NSUB    = 6E16            TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=90E-12 VJ=0.38 M=0.20
+FC=0.1 IS=1E-12 TT=1.09E-8 N=1 BV=30.2)
**************************************************************** 
.MODEL RTEMP RES (TC1=6E-3 TC2=5.5E-6)
****************************************************************  
.ENDS Si5511N
*P-CH
.SUBCKT Si5511P D G S
M1  3  GX S S PMOS W=345695u L=0.25u            
M2  S  GX S D NMOS W=345695u L=0.35u 
RG  G  GX     7.7
R1  D  3      RTEMP 3E-2
CGS GX S      230E-12
DBD D  S      DBD
***************************************************************  
.MODEL  PMOS        PMOS ( LEVEL  = 3          TOX    = 3E-8
+ RS     = 3E-2            RD     = 0          NSUB   = 4E16
+ KP     = 6.2E-6          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7       KAPPA  = 4E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0          CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3          TOX    = 3E-8
+NSUB    = 2.5E17          TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=30E-12 VJ=0.38 M=0.30
+RS=0.1 FC=0.5 IS=1E-12 TT=2.36E-8 N=1 BV=30.2)
*************************************************************** 
.MODEL RTEMP RES (TC1=7E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS Si5511P