*Oct 16, 2006
*Doc. ID: 79837, ECN #, Rev. A
*File Name: Si4833ADY_PS.txt and Si4833ADY_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si4833ADY D G S A K
XM1  D G S  Si4833ADY_PMOS
XD1  A K    Si4833ADY_SCHOTTKY
.ENDS Si4833ADY
.SUBCKT Si4833ADY_PMOS D G S
M1  3  GX S S PMOS W=647931u L=0.25u    
M2  S  GX S D NMOS W=647931u L=0.45u   
RG  G  GX     8
R1  D  3      RTEMP 18E-3
CGS GX S      270E-12
DBD D  S      DBD
************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3          TOX    = 5E-8
+ RS     = 28E-3           RD     = 0          NSUB   = 1E17  
+ KP     = 4E-6            UO     = 400             
+ VMAX   = 0               XJ     = 5E-7       KAPPA  = 1E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0          CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3          TOX    = 5E-8
+NSUB    = 1.2E17          NFS    = 1E12       TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=110E-12 VJ=0.38 M=0.35
+RS=0.1 FC=0.5 IS=1E-12 TT=1.12E-8 N=1 BV=30.2)
*************************************************************** 
.MODEL RTEMP RES (TC1=6E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS Si4833ADY_PMOS
.subckt Si4833ADY_SCHOTTKY 7 5
r1 6 5  rtemp 0.036
d1 7 6  sdiode 
****************************************************
.model sdiode d (cjo=300e-12 vj=0.38 xti=2 
+rs=0 fc=0.5 is=1.4e-6 ikf=0.85 eg=0.69 n=1 bv=32)
**************************************************** 
.model rtemp res (tc1=0.31e-2 tc2=30e-6)
.ENDS Si4833ADY_SCHOTTKY