*December 18, 2006
*Doc. ID: 79853, S-62520, Rev. A
*File Name: SUU_SUD50N04-25P_PS.txt and SUU_SUD50N04-25P_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SUU/SUD50N04-25P D G S
M1  3  GX S S NMOS W=1357854u L=0.25u    
M2  S  GX S D PMOS W=1357854u L=0.45u  
RG  G  GX     1.6
R1  D  3      RTEMP 10E-3
CGS GX S      1060E-12
DBD S  D      DBD
************************************************************* 
.MODEL  NMOS       NMOS (  LEVEL  = 3         TOX    = 4E-8
+ RS     = 6.2E-3          RD	  = 0	      NSUB   = 2.8E17              
+ KP     = 1.7E-5          UO     = 650 	
+ VMAX   = 0               XJ     = 5E-7      KAPPA  = 2E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0         CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
************************************************************** 
.MODEL  PMOS       PMOS (  LEVEL  = 3         TOX    = 4E-8
+NSUB    = 3E16            IS  	  = 0	      TPG    = -1)           
 ************************************************************* 
.MODEL DBD D (CJO=300E-12 VJ=0.38 M=0.32 EG=1.17 
+FC=0.1 TT=1.76E-8 T_MEASURED=25 BV=40.2 
+RS=5.412e-03 N=1.133 IS=1.144e-11   
+XTI=2.277 TRS1=2.712e-03)
************************************************************** 
.MODEL RTEMP RES (TC1=8E-3 TC2=5.5E-6)
************************************************************** 
.ENDS