*December 18, 2006
*Doc. ID: 79868, S-62522, Rev. A
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SUU/SUD50N04-06P D G S
M1  3  GX S S NMOS W=7894500u L=0.25u    
M2  S  GX S D PMOS W=7894500u L=0.45u  
RG  G  GX     1.2
R1  D  3      RTEMP 3E-3
CGS GX S      3900E-12
DBD S  D      DBD
************************************************************* 
.MODEL  NMOS       NMOS (  LEVEL  = 3         TOX    = 4E-8
+ RS     = 2E-3            RD	  = 0	      NSUB   = 2.43E17              
+ KP     = 8E-6            UO     = 650 	
+ VMAX   = 0               XJ     = 5E-7      KAPPA  = 5E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0         CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5      TCV    = 3.1E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
************************************************************** 
.MODEL  PMOS       PMOS (  LEVEL  = 3         TOX    = 4E-8
+NSUB    = 3E16            IS  	  = 0	      TPG    = -1)           
 ************************************************************* 
.MODEL DBD D (CJO=800E-12 VJ=0.38 M=0.37  
+FC=0.5 TT=2.22E-8 TREF=25 BV=40.2 
+RS=3.57e-03 N=1.02 IS=1.46e-10 IK=2.07 EG=9.65e-1 
+XTI=3.02 TRS=-9.98e-04)
************************************************************** 
.MODEL RTEMP R (TC1=7.5E-3 TC2=5.5E-6)
************************************************************** 
.ENDS