*January 21, 2008
*Doc. ID: 79880, S-80010, Rev. B
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.subckt si4620dy d g s k a
x1 d g s si4620dy_mos
x2 a k   si4620dy_schottky
.ends si4620dy
.SUBCKT Si4620DY_mos D G S
M1  3  GX S S NMOS W=698305u L=0.25u 
M2  S  GX S D PMOS W=698305u L=0.35u 
RG  G  GX     2.8
R1  D  3      RTEMP 11E-3
CGS GX S      390E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS       NMOS ( LEVEL  = 3            TOX    = 5E-8
+ RS     = 12E-3          RD     = 0            NSUB   = 2.67E17  
+ KP     = 1.35E-5        UO     = 650             
+ VMAX   = 0              XJ     = 5E-7         KAPPA  = 1E-1
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0               
+ CGSO   = 0              CGDO   = 0            CGBO   = 0 
+ TLEV   = 1              BEX    = -1.5         TCV    = 4.4E-3
+ NFS    = 0.8E12         DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS       PMOS ( LEVEL  = 3            TOX    = 5E-8
+NSUB    = 5E16           IS     = 0		TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=200E-12 VJ=0.38 M=0.28 EG=1.17
+FC=0.1 TT=4.47E-8 TREF=25 BV=30.5
+RS=1.393e-02 N=1.195 IS=2.388e-11   
+XTI=2.139 TRS=2.328e-03)
**************************************************************** 
.MODEL RTEMP R (TC1=8E-3 TC2=5.5E-6)
**************************************************************** 
.ends si4620dy_mos
.subckt si4620dy_schottky 7 5
r1 7 1 5.71e-02 tc=1.33e-02,-1.06e-04
d1 1 5 sdsm
r2 7 2 4.52e-02 tc=1.14e-01,-2.75e-05
d2 2 5 sdlg
.model sdsm d (
+is=3.70e-07 n=6.74e-01 ik=1 eg=5.76e-01
+xti=2e-01 
+bv=50 ibv=1e-1 tlev=1)
.model sdlg d (
+is=2.36e-04 n=1.51 ik=1 eg=2.19e-02
+xti=2.23e+1
+bv=50 ibv=1e-1 tlev=1
+vj=0.386 cjo=290e-12 m=0.302)
.ends si4620dy_schottky