*January 29, 2007
*Doc. ID: 79884, S-70174, Rev. A
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si1065X D G S
M1  3  GX S S PMOS W=574000u L=0.25u            
M2  S  GX S D NMOS W=574000u L=0.53u
RG  G  GX     10
R1  D  3      RTEMP 4.5E-2
CGS GX S      220E-12
DBD D  S      DBD
***************************************************************  
.MODEL  PMOS        PMOS ( LEVEL  = 3          TOX    = 1.7E-8
+ RS     = 4.8E-2          RD     = 0          NSUB   = 2.7E16
+ KP     = 9E-6            UO     = 400             
+ VMAX   = 0               XJ     = 5E-7       KAPPA  = 3E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0          CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5       TCV    = 2E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3          TOX    = 1.7E-8
+NSUB    = 2E17            TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=120E-12 VJ=0.38 M=0.38
+RS=0.1 FC=0.5 IS=1E-12 TT=8.79E-9 N=1 BV=12.2)
*************************************************************** 
.MODEL RTEMP R (TC1=9E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS