*July 30, 2007
*Doc. ID: 79888, S-71561, Rev. A
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si1067X D G S
M1  3  GX S S PMOS W=574000u L=0.25u            
M2  S  GX S D NMOS W=574000u L=0.35u
RG  G  GX     8.8
R1  D  3      RTEMP 5.5E-2
CGS GX S      180E-12
DBD D  S      DBD
***************************************************************  
.MODEL  PMOS        PMOS ( LEVEL  = 3          TOX    = 1.7E-8
+ RS     = 5.3E-2          RD     = 0          NSUB   = 3E16
+ KP     = 1.23E-5         UO     = 400             
+ VMAX   = 0               XJ     = 5E-7       KAPPA  = 2E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0          CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5       TCV    = 1.8E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3          TOX    = 1.7E-8
+NSUB    = 7E16            TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=60E-12 VJ=0.38 M=0.38
+RS=0.1 FC=0.5 IS=1E-12 TT=8.84E-9 N=1 BV=21)
*************************************************************** 
.MODEL RTEMP R (TC1=5E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS