*January 29, 2007
*Doc. ID: 79897, S-70135, Rev. A
*File Name: SiA811DJ_PS.txt and SiA811DJ_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.subckt  SiA811DJ d g s a k
x1 d g s SiA811DJ_mos
x2 a k   SiA811DJ_schottky
.ends SiA811DJ
.SUBCKT SiA811DJ_mos D G S
M1  3  GX S S PMOS W=325941u L=0.25u            
M2  S  GX S D NMOS W=325941u L=0.30u
RG  G  GX     8
R1  D  3      RTEMP 1.05E-2
CGS GX S      240E-12
DBD D  S      DBD
***************************************************************  
.MODEL  PMOS        PMOS ( LEVEL  = 3          TOX    = 1.7E-8
+ RS     = 5E-2            RD     = 0          NSUB   = 1.4E16
+ KP     = 1.15E-5         UO     = 400             
+ VMAX   = 0               XJ     = 5E-7       KAPPA  = 2E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0          CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3          TOX    = 1.7E-8
+NSUB    = 3E17            IS	  = 0	       TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=40E-12 VJ=0.38 M=0.20
+FC=0.5 TT=8.68E-9 T_MEASURED=25 BV=20.2
+RS=3.70e-2 N=0.98 IS=1.11e-11 IKF=5.04e-2 EG=0.98 
+XTI=0.23 TRS1=-5.2e-4)
*************************************************************** 
.MODEL RTEMP RES (TC1=15E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS SiA811DJ_mos
.subckt SiA811DJ_schottky 7 5
r1 7 1 7.97e-02 tc=2.32e-02,-1.52e-04
d1 1 5 sdsm
r2 7 2 1.05 tc=0.6,1.96e-02
d2 2 5 sdlg
.model sdsm d (
+is=1.81e-06 n=9.32e-01 ikf=1 eg=6.23e-01
+xti=2.19e-01 
+bv=50 ibv=1e-1 )
.model sdlg d (
+is=1.95e-05 n=1.61 ikf=1 eg=4.9e-01
+xti=10
+bv=50 ibv=1e-1 
+vj=0.233 cjo=261e-12 m=0.393)
.ends SiA811DJ_schottky