*February 26, 2007
*Doc. ID: 79901, S-70348, Rev. A
*File Name: Si4621DY_PS.txt and Si4621DY_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.subckt  Si4621DY d g s a k
x1 d g s Si4621DY_mos
x2 a k   Si4621DY_schottky
.ends Si4621DY
.SUBCKT Si4621DY_mos D G S
M1  3  GX S S PMOS W=770406u L=0.25u           
M2  S  GX S D NMOS W=770406u L=0.50u   
RG  G  GX     9
R1  D  3      RTEMP 12E-3
CGS GX S      250E-12
DBD D  S      DBD
***************************************************************  
.MODEL  PMOS        PMOS ( LEVEL  = 3          TOX    = 5E-8
+ RS     = 17E-3           RD     = 0          NSUB   = 1.28E17
+ KP     = 4.3E-6          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7       KAPPA  = 1E-2
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0          CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3          TOX    = 5E-8
+NSUB    = 8E16            IS     = 0  	       TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=180E-12 VJ=0.38 M=0.29
+FC=0.5 TT=1.03E-8 T_MEASURED=25 BV=21
+RS=1.684e-02 N=1.074 IS=2.274e-12 IKF=5.694  
+EG=1.179 XTI=2.193 TRS1=2.233e-03)
*************************************************************** 
.MODEL RTEMP RES (TC1=6E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS Si4621DY_mos
.subckt Si4621DY_schottky 7 5
r1 7 1 7.97e-02 tc=2.32e-02,-1.52e-04
d1 1 5 sdsm
r2 7 2 1.05 tc=0.6,1.96e-02
d2 2 5 sdlg
.model sdsm d (
+is=1.81e-06 n=9.32e-01 ikf=1 eg=6.23e-01
+xti=2.19e-01 
+bv=50 ibv=1e-1 )
.model sdlg d (
+is=1.95e-05 n=1.61 ikf=1 eg=4.9e-01
+xti=10
+bv=50 ibv=1e-1 
+vj=0.233 cjo=261e-12 m=0.393)
.ends Si4621DY_schottky