*February 26, 2007
*Doc. ID: 79929, S-70346, Rev. A
*File Name: SiA443DJ_PS.txt and SiA443DJ_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SiA443DJ D G S
M1  3  GX S S PMOS W=668673u L=0.25u            
M2  S  GX S D NMOS W=668673u L=0.30u
RG  G  GX     9
R1  D  3      RTEMP 15E-3
CGS GX S      600E-12
DBD D  S      DBD
***************************************************************  
.MODEL  PMOS        PMOS ( LEVEL  = 3          TOX    = 1.7E-8
+ RS     = 11E-3           RD     = 0          NSUB   = 1E16
+ KP     = 9E-6            UO     = 400             
+ VMAX   = 0               XJ     = 5E-7       KAPPA  = 6E-4
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0          CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3          TOX    = 1.7E-8
+NSUB    = 2.6E17          IS     = 0          TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=100E-12 VJ=0.38 M=0.20
+FC=0.5 TT=9.61E-9 T_MEASURED=25 BV=22
+RS=1.584e-02 N=9.650e-01 IS=7.051e-11 IKF=0.01
+EG=1.054 XTI=2.956e-02 TRS1=1.669e-04)
*************************************************************** 
.MODEL RTEMP RES (TC1=6.5E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS