*February 26, 2007
*Doc. ID: 79933, S-70347, Rev. A
*File Name: Si1958DH_PS.txt and Si1958DH_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si1958DH D G S
M1  3  GX S S NMOS W=92629u L=0.25u  
M2  S  GX S D PMOS W=92629u L=0.40u  
RG  G  GX     4
R1  D  3      RTEMP 7.5E-2
CGS GX S      95E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 3E-8
+ RS     = 4.4E-2          RD     = 0           NSUB   = 2.7E17   
+ kp     = 1.8E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 5E-3
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 3E-8
+NSUB    = 1E17            IS     = 0           TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=22E-12 VJ=0.38 M=0.11 
+FC=0.5 TT=2.05E-8 T_MEASURED=25 BV=22 
+RS=5.438e-02 N=1.031 IS=1e-11 IKF=0.01
+EG=1.1 XTI=1.255 TRS1=1.731e-03)
**************************************************************** 
.MODEL RTEMP RES (TC1=6E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS