*March 12, 2007
*Doc. ID: 79957, S-70427, Rev. A
*File Name: SUM52N20-39P_PS.txt and SUM52N20-39P_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SUM52N20-39P D G S
M1  3  GX S S NMOS W=8810652u L=0.25u  
M2  S  GX S D PMOS W=8810652u L=0.40u
RG  G  GX     1.2
R1  D  3      RTEMP 24E-3
CGS GX S      3800E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS       NMOS ( LEVEL  = 3            TOX    = 10E-8
+ RS     = 6E-3           RD     = 0            NSUB   = 3E17 
+ KP     = 5.6E-6         UO     = 650             
+ VMAX   = 0              XJ     = 5E-7         KAPPA  = 1E-1
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0               
+ CGSO   = 0              CGDO   = 0            CGBO   = 0 
+ NFS    = 0.8E12         DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS       PMOS ( LEVEL  = 3            TOX    = 10E-8
+NSUB    = 1E16           TPG    = -1)   
****************************************************************  
.MODEL DBD D (CJO=1000E-12 VJ=0.38 M=0.39
+RS=1 FC=0.5 IS=1E-12 TT=8.12E-9 N=1 BV=204)
**************************************************************** 
.MODEL RTEMP RES (TC1=8.5E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS