*March 12, 2007
*Doc. ID: 79960, S-70426, Rev. A
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SUM36N20-54P D G S
M1  3  GX S S NMOS W=6476320u L=0.25u  
M2  S  GX S D PMOS W=6476320u L=0.40u
RG  G  GX     1.2
R1  D  3      RTEMP 44E-3
CGS GX S      2700E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS       NMOS ( LEVEL  = 3            TOX    = 10E-8
+ RS     = 1E-3           RD     = 0            NSUB   = 2.15E17 
+ KP     = 3.6E-6         UO     = 650             
+ VMAX   = 0              XJ     = 5E-7         KAPPA  = 1E-3
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0               
+ CGSO   = 0              CGDO   = 0            CGBO   = 0 
+ TLEV   = 1              BEX    = -1.9         TCV    = 14E-3
+ NFS    = 0.8E12         DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS       PMOS ( LEVEL  = 3            TOX    = 10E-8
+NSUB    = 1E16           TPG    = -1)   
****************************************************************  
.MODEL DBD D (CJO=900E-12 VJ=0.38 M=0.39
+RS=1 FC=0.5 IS=1E-12 TT=9.14E-11 N=1 BV=204)
**************************************************************** 
.MODEL RTEMP R (TC1=7E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS