*March 26, 2007
*Doc. ID: 79972, S-70504, Rev. A
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SiE830DF D G S
M1  3  GX S S NMOS W=6705166u L=0.25u 
M2  S  GX S D PMOS W=6705166u L=0.20u
RG  G  GX     1  
R1  D  3      RTEMP 14E-4
CGS GX S      3600E-12
DBD S  D      DBD
************************************************************  
.MODEL  NMOS         NMOS (LEVEL  = 3        TOX    = 3E-8
+ RS     = 18E-4           RD     = 0        NSUB   = 3.7E17  
+ KP     = 2E-5            UO     = 650             
+ VMAX   = 0               XJ     = 5E-7     KAPPA  = 1E-1
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0        CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5     TCV    = 2.7E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
************************************************************  
.MODEL  PMOS         PMOS (LEVEL  = 3        TOX    = 3E-8
+NSUB    = 4E16            IS     = 0	     TPG    = -1)   
************************************************************  
.MODEL DBD D (CJO=1350E-12 VJ=0.38 M=0.27
+FC=0.5 TT=2.01E-8 TREF=25 BV=32 
+RS=5.35E-04 N=8.75E-01 IS=1e-11 IKF=0.01
+EG=1.14 XTI=2.65 TRS=4.72e-06 )
************************************************************ 
.MODEL RTEMP R (TC1=9.5E-3 TC2=5.5E-6)
************************************************************  
.ENDS