***********************************************************
Copyright 2020 Vishay Intertechnology, Inc.
All rights reserved.
***********************************************************
*produced by Vishay General Semiconductor Taiwan
*Allen Su, 2017/2/21
*   PSPICE
*                    anode     cathode
* Reverse direction: node 9 <- node 2
.SUBCKT smbj3v3 9 2
DF 9 90 DFMOD
.MODEL DFMOD D N = 1.50101 IS = 9.8398E-010 RS = 0.0122063
+ EG = 1.21397 XTI = 0.519258
+ CJO = 5.2E-009 VJ = 1.3475 M = 0.5 FC = 0.5
+ TT = 1E-008 T_MEASURED = 25 T_ABS = 25
* Leakage
RL 9 90 RLMOD 17572.5
.MODEL RLMOD RES TC1 = 0 TC2 = 0 T_MEASURED = 25
* Breakdown
RBD 90 4 0.0615177
EBD 4 3 10 20 1
DBD 3 9 DBDMOD
RBD1 90 6 0.0288951
EBD1 6 7 30 40 1
DBD1 7 9 DBDMOD
.MODEL DBDMOD D IS = 1E-015 N = 0.5 T_MEASURED = 25 T_ABS = 25
IBVC 0 10 0.001
RBVC 10 0 RBVCMOD 4100.75
.MODEL RBVCMOD R TC1 = -0.00053 T_MEASURED = 25
IBVC1 0 30 0.001
RBVC1 30 0 8784.37
RBDX 20 23 0.0615177
DBVC 23 0 DBDMOD
IBVD 0 20 0.001
RBDX1 40 43 0.0288951
DBVC1 43 0 DBDMOD
IBVD1 0 40 49.999
L1 90 2 1E-015
.ENDS