**********************************
* Model created by               *
*   Uni.Dipl.-Ing. Arpad Buermen *
*   arpad.burmen@ieee.org        *
* Copyright:                     *
*   Thomatronik GmbH, Germany    *
*   info@thomatronik.de          *
**********************************
* March 2001
*   SPICE3
* Bidirectional
.SUBCKT sa5v0ca 1 2
DF 9 90 DFMOD TEMP = 25
.MODEL DFMOD D N = 1.85483 IS = 1.44924E-008 RS = 0.0179293
+ EG = 1.11 XTI = 3
+ CJO = 4.56E-009 VJ = 0.24689 M = 0.42 FC = 0.5
+ TT = 1E-008 TNOM = 25
* Leakage
RLF 9 90 4212.47 RLMOD
RLR 1 9 4212.47 RLMOD
.MODEL RLMOD R TC1 = 0 TC2 = 0 TNOM = 25
* Breakdown
RBD 90 4 0.0161659
EBD 4 3 10 20 1
DBD 3 9 DBDMOD TEMP = 25
* Reverse
DR 9 1 DFMOD TEMP = 25
RBDR 1 94 0.0161659
EBDR 94 93 10 20 1
DBDR 93 9 DBDMOD TEMP = 25
.MODEL DBDMOD D IS = 1E-015 N = 0.5 TNOM = 25
IBVC 0 10 0.001
RBVC 10 0 6825 RBVCMOD
.MODEL RBVCMOD R TC1 = 5.86081E-005 TNOM = 25
RBDX 20 23 0.0161659
DBVC 23 22 DBDMOD TEMP = 25
DBVF 22 0 DFMOD TEMP = 25
IBVD 0 20 0.01
L1 90 2 1E-015
.ENDS