*************************************************
* Copyright 2020 © Vishay Intertechnology, Inc. *
* All rights reserved.                          *
*************************************************
*Feb 7, 2021
*DD Vishay semiconduttori italiana SPA
*davide.dapra@vishay.com
*File Name: TPSMP12A.txt
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product datasheet. Designers should refer to the
*appropriate datasheet of the same number for guaranteed specification
*limits.


*Model fit device at 25°C
*DEVICE=TPSMP12A,X

**************************************************** 

.SUBCKT TPSMP12A 9 2
* 9 anode 2 cathode
*Forward
DF 9 90 DFMOD
.MODEL DFMOD D N = 0.577 IS = 2.1729E-18  RS = 0.07379
+ EG = 1.11 XTI = 3
+ CJO = 9.1373E-010 VJ = 28.46 M = 4.318 FC = 0.5
+ TT = 5E-009
* Leakage
* RL 9 90 leakage from DF junction
* Breakdown
RBD 90 4 0.253
EBD 4 3 10 20 1
DBD 3 9 DBDMOD 
.MODEL DBDMOD D IS = 1E-016 N = 0.5
IBVC 0 10 0.001
RBVC 10 0 12000 TC1 = 0.00078
RBDX 20 23 0.253
DBVC 23 0 DBDMOD
IBVD 0 20 0.001
*Stray inductance for current return under device
L1 90 2 3.4E-10
.OPTION tnom 27

.ENDS