*************************************************
* Copyright 2020  © Vishay Intertechnology, Inc.*
* All rights reserved.                          *
*************************************************
*June 18, 2022
*DD Vishay semiconduttori italiana SPA
*davide.dapra@vishay.com
*File Name: XMC7K24CA.txt
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product datasheet. Designers should refer to the
*appropriate datasheet of the same number for guaranteed specification
*limits.


*Model fit device from -55°C to 175°C
*DEVICE=XMC7K24CA,X

****************************************************

.SUBCKT XMC7K24CA 1 2
DF 9 90 DFMOD
.MODEL DFMOD D CJO=3.15n
* Leakage
RLF 9 90 RLMOD 8E6
RLR 1 9 RLMOD 8E6
CJ 1 90 1.2p
.MODEL RLMOD RES TC1 = 0 TC2 = 0 T_MEASURED = 25
* Breakdown
RBD 90 4 0.024
EBD 4 3 10 20 1
DBD 3 9 DBDMOD
* Reverse
DR 9 1 DFMOD
RBDR 1 94 0.024
EBDR 94 93 10 20 1
DBDR 93 9 DBDMOD
.MODEL DBDMOD D
B1 0 10 I=I(rbd)>1e-6 ? 6.76e-4 : I(rbdr)>1e-6 ? 6.76e-4 : 0.001
RBVC 10 0 RBVCMOD 28271
CBVC 10 0 16p
.MODEL RBVCMOD RES TC1 = 0.378m TC2 = -3.467u T_MEASURED = 25
RBDX 20 23 0.024
DBVC 23 22 DBDMOD
DBVF 22 0 DFMOD
IBVD 0 20 0.001
L1 90 2 1.2E-09

.ENDS