*March 14, 2005
*Doc. ID: 77636, S-50396, Rev. A
.SUBCKT Si2312BDS 4 1 2
M1  3 1 2 2 NMOS W=651559u L=0.50u
M2  2 1 2 4 PMOS W=651559u L=0.30u
R1  4 3     RTEMP 12E-3
CGS 1 2     320E-12
DBD 2 4     DBD
************************************************************  
.MODEL  NMOS        NMOS (LEVEL  = 3         TOX    = 1.7E-8
+ RS     = 8E-3           RD     = 0         NSUB   = 2.1E17   
+ KP     = 9E-5           UO     = 650             
+ VMAX   = 0              XJ     = 5E-7      KAPPA  = 1E-2
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0                             
+ CGSO   = 0              CGDO   = 0         CGBO   = 0 
+ TLEV   = 1              BEX    = -1.5      TCV    = 1.65E-3
+ NFS    = 0.8E12         DELTA  = 0.1)
************************************************************  
.MODEL  PMOS        PMOS (LEVEL  = 3         TOX    = 1.7E-8
+NSUB    = 1E17           TPG    = -1)   
************************************************************  
.MODEL DBD D (CJO=150E-12 VJ=0.38 M=0.30
+RS=0.01 FC=0.1 IS=1E-12 TT=5E-8 N=1 BV=20.5)
************************************************************ 
.MODEL RTEMP R (TC1=7E-3 TC2=5.5E-6)
************************************************************  
.ENDS