*October 8, 2007
*Doc. ID: 69412, S-72046, Rev. A
*File Name: SUP90N06-6m0P_PS.txt and SUP90N06-6m0P_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SUP90N06-6m0P D G S
M1  3  GX S S NMOS W=11381429u L=0.25u  
M2  S  GX S D PMOS W=11381429u L=0.57u
RG  G  GX     1.2
R1  D  3      RTEMP 15E-4
CGS GX S      3450E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS       NMOS ( LEVEL  = 3            TOX    = 10E-8
+ RS     = 13E-4          RD     = 0            NSUB   = 2.4E17 
+ KP     = 2E-6           UO     = 650             
+ VMAX   = 0              XJ     = 5E-7         KAPPA  = 1E-2
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0               
+ CGSO   = 0              CGDO   = 0            CGBO   = 0 
+ NFS    = 0.8E12         DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS       PMOS ( LEVEL  = 3            TOX    = 10E-8
+NSUB    = 5E15           IS	 = 0		TPG    = -1)   
****************************************************************  
.MODEL DBD D (CJO=3850E-12 VJ=0.38 M=0.50
+FC=0.5 TT=3.81e-08 T_MEASURED=25 BV=61 
+RS=2.168e-03 N=1.058 IS=7.291e-12 IKF=1000
+EG=1.211 XTI=1.278 TRS1=2.876e-03 )
**************************************************************** 
.MODEL RTEMP RES (TC1=8.7E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS