*November 19, 2007
*Doc. ID: 69699, S-72405, Rev. A
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SiA511DJ D1 G1 S1 D2 G2 S2 
X1 D1 G1 S1 SiA511N
X2 D2 G2 S2 SiA511P
.ENDS SiA511DJ
*N-CH
.SUBCKT SiA511N D G S
M1  3  GX S S NMOS W=361042u L=0.25u  
M2  S  GX S D PMOS W=361042u L=0.35u  
RG  G  GX     2.5
R1  D  3      RTEMP 15E-3
CGS GX S      280E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 1.7E-8
+ RS     = 13E-3           RD     = 0           NSUB   = 2.7E17   
+ kp     = 3.2E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 1E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5        TCV    = 2E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 1.7E-8
+NSUB    = 1.5E17          IS     = 0           TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=105E-12 VJ=0.38 M=0.20  
+FC=0.5 TT=1.07E-8 TREF=25 BV=13 
+RS=3.728e-02 N=1.36 IS=9.996e-08 IK=1000
+EG=7.984e-01 XTI=6.796e-01 TRS=3.593e-08 )
**************************************************************** 
.MODEL RTEMP R (TC1=7E-3 TC2=5.5E-6)
****************************************************************  
.ENDS SiA511N
*P-CH
.SUBCKT SiA511P D G S
M1  3  GX S S PMOS W=325941u L=0.25u            
M2  S  GX S D NMOS W=325941u L=0.40u 
RG  G  GX     7
R1  D  3      RTEMP 25E-3
CGS GX S      160E-12
DBD D  S      DBD
***************************************************************  
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 1.7E-8
+ RS     = 15E-3           RD     = 0           NSUB   = 1.7E16
+ KP     = 1.2E-5          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 3E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5        TCV    = 1.9E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 1.7E-8
+NSUB    = 5E17            IS     = 0		TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=90E-12 VJ=0.38 M=0.28
+FC=0.5 TT=8.04e-09 TREF=25 BV=12.2 
+RS=2.386e-02 N=1.701 IS=1.000e-07 IK=1000
+EG=1.052 XTI=3.947e-01 TRS=8.602e-06 )
*************************************************************** 
.MODEL RTEMP R (TC1=4.5E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS SiA511P