*February 20, 2006
*Doc. ID: 75392, S-60245, Rev. B
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SI4838DY 4 1 2
M1  3 1 2 2 NMOS W=4239943u L=0.50u
M2  2 1 2 4 PMOS W=4239943u L=0.35u
R1  4 3     RTEMP 10E-4
CGS 1 2     1050E-12
DBD 2 4     DBD
************************************************************  
.MODEL  NMOS         NMOS (LEVEL  = 3        TOX    = 1.7E-8
+ RS     = 3E-4            RD     = 0        NSUB   = 4.1E17   
+ KP     = 6E-5            UO     = 650             
+ VMAX   = 0               XJ     = 5E-7     KAPPA  = 10E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0        CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5     TCV    = 2.2E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
************************************************************  
.MODEL  PMOS         PMOS (LEVEL  = 3        TOX    = 1.7E-8
+NSUB    = 13E16           TPG    = -1)   
************************************************************  
.MODEL DBD D (CJO=3000E-12 VJ=0.38  M=0.30
+RS=0.01 FC=0.1 IS=1E-12 TT=1.7E-8 N=1 BV=12.5)
************************************************************ 
.MODEL RTEMP R (TC1=5E-3   TC2=5.5E-6)
************************************************************  
.ENDS