*Oct 31, 2005
*Doc. ID: 75703, S-52294, Rev. B
.SUBCKT Si4925BDY 4 1 2
M1  3 1 2 2 PMOS W=2411963u L=0.50u  
M2  2 1 2 4 NMOS W=2411963u L=0.70u 
R1  4 3     RTEMP 5E-3
CGS 1 2     500E-12
DBD 4 2     DBD
**************************************************************************
.MODEL  PMOS       PMOS (  LEVEL  = 3               TOX    = 5E-8
+ RS     = 15E-3           RD     = 0               NSUB   = 1.2E17
+ VMAX   = 0               XJ     = 5E-7            KAPPA  = 10E-1
+ ETA    = 1E-7            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0               CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5            TCV    = 2.8E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************************
.MODEL  NMOS       NMOS (  LEVEL  = 3               TOX    = 5E-8
+NSUB    = 4E16             NFS   = 10E11           TPG    = -1)   
*************************************************************************
.MODEL DBD D (CJO=400E-12 VJ=0.38 M=0.38
+RS=0.1 FC=0.5 IS=1E-12 TT=14E-8 N=1 BV=30.2)
*************************************************************************
.MODEL RTEMP R (TC1=12E-3  TC2=5.5E-6)
*************************************************************************
.ENDS