*June 13, 2005
*Doc. ID: 75871, S-51095, Rev. B
*File Name: Si4408DY_PS.txt and Si4408DY_PS.lib
.SUBCKT Si4408DY 4 1 2
M1  3 1 2 2 NMOS W=4641966u L=0.50u
M2  2 1 2 4 PMOS W=4641966u L=0.32u
R1  4 3     RTEMP 1.1E-3
CGS 1 2     1500E-12
DBD 2 4     DBD
************************************************************  
.MODEL  NMOS         NMOS (LEVEL  = 3        TOX    = 5E-8
+ RS     = 1.9E-3          RD     = 0        NSUB   = 1.8E17  
+ KP     = 2.4E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7     KAPPA  = 2E-1
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0        CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
************************************************************  
.MODEL  PMOS         PMOS (LEVEL  = 3        TOX    = 5E-8
+NSUB    = 5E16            TPG    = -1)   
************************************************************  
.MODEL DBD D (CJO=2200E-12 VJ=0.38  M=0.28
+RS=0.01 FC=0.1 IS=1E-12 TT=2.8E-8 N=1 BV=30.2)
************************************************************ 
.MODEL RTEMP RES (TC1=11E-3  TC2=5.5E-6)
************************************************************  
.ENDS