*Feb. 7, 2005
*Doc. ID: 76769, S-50151, Rev. B
*File Name: 2N7002E_PS.txt and 2N7002E_PS.lib
.SUBCKT 2N7002E 4 1 2  
M1  3 1 2 2 NMOS W=18981u L=0.50u 
M2  2 1 2 4 PMOS W=18981u L=0.70u
R1  4 3     RTEMP 1000E-3
CGS 1 2     23E-12
DBD 2 4     DBD
************************************************************* 
.MODEL  NMOS       NMOS ( LEVEL  = 3          TOX    = 5E-8
+ RS     = 220E-3         RD     = 0          NSUB   = 3.3E17  
+ KP     = 6.5E-5         UO     = 650             
+ VMAX   = 0              XJ     = 5E-7       KAPPA  = 2E-1
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0                           
+ CGSO   = 0              CGDO   = 0          CGBO   = 0 
+ NFS    = 0.8E12         DELTA  = 0.1)
************************************************************** 
.MODEL  PMOS       PMOS ( LEVEL  = 3          TOX    = 5E-8
+NSUB    = 1.5E16         TPG    = -1)   
************************************************************** 
.MODEL DBD D (CJO=26E-12 VJ=0.38 M=0.38
+RS=0.1 FC=0.5 IS=1E-12 TT=5E-8 N=1 BV=26)
************************************************************** 
.MODEL RTEMP RES (TC1=5E-3 TC2=5.5E-6)
************************************************************** 
.ENDS