*March 26, 2007
*Doc. ID: 76886, S-70503, Rev. B
*File Name: Si7108DN_PS.txt and Si7108DN_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si7108DN D G S
M1  3  GX S S NMOS W=3733240u L=0.50u    
M2  S  GX S D PMOS W=3733240u L=0.35u  
RG  G  GX     1.4
R1  D  3      RTEMP 9E-4
CGS GX S      1400E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 5E-8
+ RS     = 16E-4           RD     = 0           NSUB   = 2E16   
+ kp     = 1.55E-5         UO     = 650             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 5E-3
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 5E-8
+NSUB    = 4E16            IS     = 0	        TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=600E-12 VJ=0.38 M=0.20 
+FC=0.5 TT=1.39E-8 T_MEASURED=25 BV=22 
+RS=8.679e-04 N=1.18 IS=6.435e-11 IKF=1000
+EG=1.183 XTI=2.838 TRS1=3.589e-03 )
**************************************************************** 
.MODEL RTEMP RES (TC1=7.7E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS