*July 30, 2007
*Doc. ID: 77290, S-71534, Rev. B
*File Name: Si6968BEDQ_PS.txt and Si6968BEDQ_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si6968BEDQ 4 1 2
M1   3 5 2 2 NMOS W=1488376u L=0.50u   
M2   2 5 2 4 PMOS W=1488376u L=0.25u  
R1   4 3     RTEMP 9.2E-3
CGS  5 2     1100E-12
DBD  2 4     DBD
xesd 1 5 2   Si6968BEDQ_ESD
************************************************************  
.MODEL  NMOS        NMOS ( LEVEL  = 3        TOX    = 3E-8
+ RS     = 5E-3            RD     = 0        NSUB   = 2.2E17  
+ KP     = 5.7E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7     KAPPA  = 4E-1
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0        CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
************************************************************  
.MODEL  PMOS        PMOS ( LEVEL  = 3        TOX    = 3E-8
+NSUB    = 4.5E16          TPG    = -1)   
************************************************************  
.MODEL DBD D (CJO=3900E-12 VJ=0.38 M=0.38
+RS=0.01 FC=0.1 IS=1E-12 TT=5.8E-8 N=1 BV=50.2)
************************************************************ 
.MODEL RTEMP RES (TC1=6.5E-3 TC2=5.5E-6)
************************************************************  
.ENDS Si6968BEDQ
.subckt Si6968BEDQ_esd 1 5 2
rleak 1 9 497k TC=-4e-3
dleak 9 2 dleak   
.MODEL dleak d (IS=4.084e-9 XTI=776.2 EG=1.17 T_MEASURED=25 TBV1=0 N=66.44 BV=50) 
rout 1 10 102 TC=-3.253e-3
dout1 10 11 dout 5.14
dout2 11 12 dout 5.5
dout3 2  12 dout 5.14
.MODEL dout D (IS=1.824e-12 XTI=-12.48 EG=1.17 T_MEASURED=25 TBV1=-5.305e-4 N=3.064 BV=11.69)
rpoly 1 5 300 TC=1e-3
rd8 5 20 1 TC=3.841e-3
din1 20 21 dout 2.69
din2 21 22 dout 3.05
din3 2  22 dout 2.69
.ENDS Si6968BEDQ_esd