*October 22, 2007
*Doc. ID: 77318, S-72176, Rev. C
*File Name: Si7214DN_PS.txt and Si7214DN_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si7214DN D G S
M1  3  G S S  NMOS W=1226636u L=0.25u   
M2  S  G S D  PMOS W=1226636u L=0.20u   
R1  D  3      RTEMP 18E-3
CGS G  S      330E-12
DBD S  D      DBD
************************************************************** 
.MODEL  NMOS       NMOS ( LEVEL  = 3           TOX    = 5E-8
+ RS     = 12E-3          RD     = 0           NSUB   = 2.7E17  
+ KP     = 1E-5           UO     = 650             
+ VMAX   = 0              XJ     = 5E-7        KAPPA  = 3E-2
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0            
+ CGSO   = 0              CGDO   = 0           CGBO   = 0 
+ NFS    = 0.8E12         DELTA  = 0.1)
*************************************************************** 
.MODEL  PMOS       PMOS ( LEVEL  = 3           TOX    = 5E-8
+NSUB    = 3E16           TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=260E-12 VJ=0.38 M=0.28
+RS=0.1 FC=0.5 IS=1E-12 TT=5E-8 N=1 BV=31)
*************************************************************** 
.MODEL RTEMP RES (TC1=6E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS