*Jan 23, 2006
*Doc. ID: 77436, S-60074, Rev. B
*File Name: Si4420BDY_PS.txt and Si4420BDY_PS.lib
.SUBCKT Si4420BDY 4 1 2
M1  3 1 2 2 NMOS W=3930568u L=0.50u  
M2  2 1 2 4 PMOS W=3930568u L=0.30u
R1  4 3     RTEMP 1.5E-3
CGS 1 2     750E-12
DBD 2 4     DBD
****************** ********************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3            TOX    = 5E-8
+ RS     = 5E-3            RD     = 0            NSUB   = 1.95E17   
+ kp     = 3.5E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7         KAPPA  = 5E-1
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0            CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
***************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3            TOX    = 5E-8
+NSUB    = 2E16            TPG    = -1)   
***************************************************************** 
.MODEL DBD D (CJO=800E-12 VJ=0.38 M=0.29 
+FC=0.1 IS=1E-12 TT=5E-8 N=1 BV=30.2)
***************************************************************** 
.MODEL RTEMP RES (TC1=12E-3 TC2=5.5E-6)
***************************************************************** 
.ENDS
 
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.